/////////////////////////////////////////////////////////////////
//
// This .TSK file will search all valid connections looking for a
// NOT-LOGGED-IN connection which it will then clear.
//
/////////////////////////////////////////////////////////////////
//
// Variables used:
//
//   %0 : Connection counter
//   %1 : Connection name
//
/////////////////////////////////////////////////////////////////
 
 
// First, define user variable %0 to the first valid connection
 
DEFINE %0 0001
 
 
// Next, loop through the connections until %0 is > %CONNS_PEAK%
 
WHILE %0<=%CONNS_PEAK%
 
 
  // Now, define user variable %1 to the user name logged into the
  // connection (%1 will equal NOT-LOGGED-IN is the connection is
  // active but no one is logged in and %1 will equal INACTIVE if
  // the connection is not currently in-use/allocated)
 
  DEFINE %1 %CONN_NAME_%0%
 
 
  // Check if the conection is INACTIVE or NOT-LOGGED-IN
  // (NOTE: This IF/ELSE/ENDIF block uses the default format.)
 
  IF %1==INACTIVE OR %1==NOT-LOGGED-IN
 
 
    // This ECHO command will only execute if the connection is
    // INACTIVE or NOT-LOGGED-IN
 
    ECHO Connection %0 is currently %1
 
 
    // Check if the connection is NOT-LOGGED-IN.  If so, clear it!
    // (NOTE: This IF/END block uses the System Login Script format.)
 
    IF %1==NOT-LOGGED-IN THEN BEGIN
      ECHO Clearing connection %0
      CLEAR STATION %0
    END
 
 
  ELSE
 
    // This ECHO command will only execute if the connection has
    // an active user connection
 
    ECHO Connection %0 in use by %1 (ID: %CONN_ID_%0%) on %CONN_ADDRESS_%0%
  ENDIF
 
 
  // Finally, increment %0 and repeat the loop
 
  DEFINE %0 %0+=1
 
LOOP